點擊關(guān)注 【秋葉 Excel】
發(fā)送【7】 領(lǐng) 1000 篇 Excel 精選教程！
作者：竺蘭
編輯：竺蘭
PS.文末下載配套練習(xí)文件！
對于得了函數(shù)恐懼癥的 Excel 小白來講，最最最最最痛苦的事情是什么？
不知道用哪個函數(shù)？
是我明明知道這個函數(shù)的名字，卻不知道怎么寫公式！
就比如在 Excel 界「稱霸一方」的查找函數(shù) VLOOKUP，懸浮窗早已給出了答案，但在小白眼里就是一堆神秘字符。
所以今天，我為大家準備了14 個常見常用的 VLOOKUP 函數(shù)經(jīng)典用法，助力大家提高效率準點下班。
單條件查找
案例：根據(jù)條件「葡萄」，查找「數(shù)量」。
公式：
=VLOOKUP(E2,B2:C21,2,FALSE)VLOOKUP 基本語法見下圖：
隱藏亂碼
案例：隱藏 F 列出現(xiàn)的亂碼#N/A。
公式：
=IFERROR(VLOOKUP(E2,B2:C21,2,FALSE),"")公式說明：""的含義是：如果前面的 VLOOKUP 函數(shù)中存在錯誤的參數(shù)，那么在顯示結(jié)果的單元格中顯示為空。
多條件查找
案例：根據(jù)兩個條件「姓名」和「科目」，查找「成績」。
公式：
=VLOOKUP(F3&G3,A:D,4,FALSE)公式說明：添加輔助列，將兩個條件用&符號組合在一起，變成一個條件，再用 VLOOKUP 函數(shù)的基礎(chǔ)語法進行查找。
模糊查找
案例：根據(jù)「課程簡稱」，查找「課程全稱」。
公式：
=VLOOKUP("*"&C2&"*",$A$1:$A$8,1,FALSE)公式說明：將要查找的簡稱前后都用&連接符加上一個「*」，就可以來替代包含該簡稱的數(shù)據(jù)了。
分段統(tǒng)計
案例：根據(jù)「金額」，查看所在「區(qū)間」。
公式：
=VLOOKUP(C2,$F$2:$G$9,2,TRUE)公式說明：
? 使用了 VLOOKUP 近似匹配的特殊用法，第四參數(shù)，需用 True，或者 1；
? 區(qū)間起點必須是第 2 參數(shù)區(qū)域的首列；
? 第 2 參數(shù)區(qū)域需用 $ 鎖定，確保不偏移。
注意：使用這個公式有條件限制。一是查找值必須為數(shù)字；二是查找區(qū)域的數(shù)字必須從小到大排序。
如果你想輕松學(xué)習(xí)一門 Excel 技能，解決職場實際需求，提高效率，可以來秋葉 Excel 3 天集訓(xùn)營哦~
秋葉 Excel 3 天集訓(xùn)營
3 天學(xué)習(xí)+課后實踐+助教答疑
現(xiàn)在加入
免費學(xué)習(xí)
還送【35 個函數(shù)使用說明手冊】
案例：根據(jù)「姓名」，查找一月、二月、三月的「銷售額」。
公式：
=VLOOKUP($A15,$A$2:$D$12,COLUMN(B1),0)公式說明：Column(B1)的結(jié)果是 2，當(dāng)公式向右復(fù)制時可以生成 3，4，5，……
逆向查找
案例：查找區(qū)域「編號」列在返回區(qū)域「水果」列的左側(cè)，可以使用 VLOOKUP+IF 函數(shù)來進行查找。
公式：
=VLOOKUP(E2,IF({1,0},B2:B21,A2:A21),2,FALSE)公式說明：利用 IF 函數(shù)構(gòu)造數(shù)組，將 B 列和 A 列位置互換，再用 VLOOKUP 函數(shù)正常查找。
多表查找
如果參與匹配的表有多個，并且可以通過條件來判斷數(shù)據(jù)存在于哪張表，還是可以用 VLOOKUP+IF 函數(shù)的組合來實現(xiàn)多表查找。
案例：不同店鋪的數(shù)據(jù)放在不同的表格中，需要查找 2 店編號 005 產(chǎn)品的數(shù)量。
公式：
=VLOOKUP(B2,IF(A2="1 店",A6:C12,E6:G14),3,0)公式說明：用 IF 函數(shù)判斷 A2 單元格的數(shù)值是否為 1 店，是則返回 A6:C12，不是則返回 E6:G14。然后用 VLOOKUP 查找。
跨表查找
如果不知道查找值位于哪張工作表，或者表的數(shù)量太多，可以使用：
VLOOKUP+INDIRECT+LOOKUP+COUNTIF
案例：根據(jù)「水果」，在多個表格查找數(shù)量。
公式：
=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"水果 1";"水果 2";"水果 3"}&"!A:A"),A2),{"水果 1";"水果 2";"水果 3"})&"!A:B"),2,0)公式說明：
A2：VLOOKUP 的查找值；
{...}數(shù)組里的內(nèi)容：多個工作表名稱，用分號分隔；
A:A：查找值在各個表中的哪一列，需要確定各個表的該列是否存在這個查找值；
A:B：VLOOKUP 的查找區(qū)域；
2：返回值的列數(shù)，姓名是在 A:B 區(qū)域中的第 2 列。
如果還想掌握更多 Excel 實用技巧~
建議你 來秋葉 Excel 3 天集訓(xùn)營，由大神帶你學(xué)習(xí)表格設(shè)計+數(shù)據(jù)處理+數(shù)據(jù)可視化，讓工作更輕松！
秋葉 Excel 3 天集訓(xùn)營
原價 99 元
現(xiàn)在限時免費
添加 Excel 班主任微信
助你提高效率、升職加薪！
交叉查詢
案例：根據(jù)「列號」和「行號」，查找姓名。
公式：
=VLOOKUP(I2,A2:F11,MATCH(I1,A1:F1,0))公式說明：用 MATCH 得出的結(jié)果即為 VLOOKUP 函數(shù)第 3 參數(shù)，返回被查找區(qū)域的第幾列。
查找最后一個值
案例：查詢「水果」的「最后一次銷量」。
公式：
=VLOOKUP(COUNTIF($C$2:$C$11,F2)&F2,$B$1:$D$11,3,FALSE)公式說明：關(guān)于用 COUNTIF 函數(shù)做輔助列查找最后一個出現(xiàn)的值相關(guān)的做法，之前有一篇文章講過：
不規(guī)范數(shù)據(jù)查找
如果數(shù)據(jù)肉眼看上去一模一樣，但怎么都查找不到，很有可能是因為數(shù)據(jù)當(dāng)中存在空格或不可見字符。
這時可以使用 SUBSTITUTE 或 CLEAN 函數(shù)處理數(shù)據(jù)，再進行查找。
案例：根據(jù)條件「葡萄」，查找「數(shù)量」。
公式：
=VLOOKUP(SUBSTITUTE(E2," ",""),B2:C21,2,0)公式說明：先用 SUBSTITUTE 函數(shù)將「橙子 」后面的空格替換成空，再用 VLOOKUP 查找。同理，如果是不可見字符，則使用 CLEAN 函數(shù)處理數(shù)據(jù)。
查找區(qū)域有合并單元格
查找區(qū)域存在合并單元格，會導(dǎo)致 VLOOKUP 無法正確查找到數(shù)據(jù)，因為合并單元格只有最左上角的單元格有數(shù)據(jù)，其他單元格都為空。
這時可以考慮用 VLOOKUP+OFFSET+MATCH 來完成查找。
案例：根據(jù)科目和姓名查找學(xué)生的成績。
公式：
=VLOOKUP(G3,OFFSET($B$2,MATCH(F3,A:A,)-1,):C22,2,0)公式說明：MATCH 函數(shù)定位科目所在的行號，用 OFFSET 向下偏移獲得「動態(tài)查找區(qū)域」，最后用 VLOOKUP 查找。
查找值為合并單元格
如果查找值也存在合并單元格，可以用兩個 VLOOKUP 嵌套完成查找。
案例：根據(jù)部門查找月度獎金。
公式：
=VLOOKUP(VLOOKUP("座",$D$2:D2,1),$A$2:$B$4,2,0)公式說明：在$D$2:D2 這個范圍里查找「座」這個文本，然后返回這個詞在這個區(qū)域里的最后一個文本，如果找不到，就返回這個區(qū)域里最后一個文本值。再用第二個 VLOOKUP 去查找。
VLOOKUP 的作用非常之強大，祝愿大家早日掌握！
Excel 中如此實用的函數(shù)還有很多，如果你還在為重復(fù)工作而煩惱，想提高效率節(jié)省時間做副業(yè)或享受生活，那一定要來《秋葉 Excel 3 天集訓(xùn)營》！
這里不僅有專業(yè)老師手把手教你表格排版+數(shù)據(jù)統(tǒng)計+圖表可視化，還有貼心助教隨時為你解答問題~
秋葉 Excel 3 天集訓(xùn)營
現(xiàn)在免費報名
送 35 個常用函數(shù)說明
趕緊點擊加入
最后用一張圖簡單總結(jié)下，本文介紹的所有 VLOOKUP 函數(shù)用法
當(dāng)然啦，只看不練是很難學(xué)會 VLOOKUP 的，所以我還整理了一份練習(xí)文件，大家在【秋葉Excel】公眾號后臺回復(fù)關(guān)鍵詞VVV獲取哦！
每天學(xué)點 Excel，工作效率 up~up~我們明天見！
點擊關(guān)注【秋葉 Excel】
回復(fù)關(guān)鍵詞VVV領(lǐng)取本文練習(xí)文件
熱門跟貼